mirror of
https://github.com/ziglang/zig.git
synced 2025-12-12 09:13:11 +00:00
30f2bb8464
When we're compiling compiler_rt for any WebAssembly target, we do not want to expose all the compiler-rt functions to the host runtime. By setting the visibility of all exports to `hidden`, we allow the linker to resolve the symbols during linktime, while not expose the functions to the host runtime. This also means the linker can properly garbage collect any compiler-rt function that does not get resolved. The symbol visibility for all target remains the same as before: `default`.
72 lines
2.0 KiB
Zig
72 lines
2.0 KiB
Zig
//! Ported from
|
|
//! https://github.com/llvm/llvm-project/blob/llvmorg-9.0.0/compiler-rt/lib/builtins/muldi3.c
|
|
|
|
const std = @import("std");
|
|
const builtin = @import("builtin");
|
|
const native_endian = builtin.cpu.arch.endian();
|
|
const common = @import("common.zig");
|
|
|
|
pub const panic = common.panic;
|
|
|
|
comptime {
|
|
if (common.want_aeabi) {
|
|
@export(__aeabi_lmul, .{ .name = "__aeabi_lmul", .linkage = common.linkage, .visibility = common.visibility });
|
|
} else {
|
|
@export(__muldi3, .{ .name = "__muldi3", .linkage = common.linkage, .visibility = common.visibility });
|
|
}
|
|
}
|
|
|
|
pub fn __muldi3(a: i64, b: i64) callconv(.C) i64 {
|
|
return mul(a, b);
|
|
}
|
|
|
|
fn __aeabi_lmul(a: i64, b: i64) callconv(.AAPCS) i64 {
|
|
return mul(a, b);
|
|
}
|
|
|
|
inline fn mul(a: i64, b: i64) i64 {
|
|
const x = dwords{ .all = a };
|
|
const y = dwords{ .all = b };
|
|
var r = dwords{ .all = muldsi3(x.s.low, y.s.low) };
|
|
r.s.high +%= x.s.high *% y.s.low +% x.s.low *% y.s.high;
|
|
return r.all;
|
|
}
|
|
|
|
const dwords = extern union {
|
|
all: i64,
|
|
s: switch (native_endian) {
|
|
.Little => extern struct {
|
|
low: u32,
|
|
high: u32,
|
|
},
|
|
.Big => extern struct {
|
|
high: u32,
|
|
low: u32,
|
|
},
|
|
},
|
|
};
|
|
|
|
fn muldsi3(a: u32, b: u32) i64 {
|
|
const bits_in_word_2 = @sizeOf(i32) * 8 / 2;
|
|
const lower_mask = (~@as(u32, 0)) >> bits_in_word_2;
|
|
|
|
var r: dwords = undefined;
|
|
r.s.low = (a & lower_mask) *% (b & lower_mask);
|
|
var t: u32 = r.s.low >> bits_in_word_2;
|
|
r.s.low &= lower_mask;
|
|
t += (a >> bits_in_word_2) *% (b & lower_mask);
|
|
r.s.low +%= (t & lower_mask) << bits_in_word_2;
|
|
r.s.high = t >> bits_in_word_2;
|
|
t = r.s.low >> bits_in_word_2;
|
|
r.s.low &= lower_mask;
|
|
t +%= (b >> bits_in_word_2) *% (a & lower_mask);
|
|
r.s.low +%= (t & lower_mask) << bits_in_word_2;
|
|
r.s.high +%= t >> bits_in_word_2;
|
|
r.s.high +%= (a >> bits_in_word_2) *% (b >> bits_in_word_2);
|
|
return r.all;
|
|
}
|
|
|
|
test {
|
|
_ = @import("muldi3_test.zig");
|
|
}
|