From 39c0c24b5659bbcaec0a6f5ba4acc8666e3b8086 Mon Sep 17 00:00:00 2001
From: Ryo Ota <nwtgck@nwtgck.org>
Date: Fri, 21 Apr 2023 01:08:15 +0900
Subject: [PATCH] fix memory leaks and add an HTTP test

---
 lib/std/http/Client.zig | 69 +++++++++++++++++++++++++++++++++++++++++
 lib/std/http/Server.zig |  5 ++-
 2 files changed, 73 insertions(+), 1 deletion(-)

diff --git a/lib/std/http/Client.zig b/lib/std/http/Client.zig
index 3de15774d1..661dcaab5b 100644
--- a/lib/std/http/Client.zig
+++ b/lib/std/http/Client.zig
@@ -1046,3 +1046,72 @@ test {
 
     std.testing.refAllDecls(@This());
 }
+
+test "client requests server" {
+    const builtin = @import("builtin");
+
+    // This test requires spawning threads.
+    if (builtin.single_threaded) {
+        return error.SkipZigTest;
+    }
+
+    const native_endian = comptime builtin.cpu.arch.endian();
+    if (builtin.zig_backend == .stage2_llvm and native_endian == .Big) {
+        // https://github.com/ziglang/zig/issues/13782
+        return error.SkipZigTest;
+    }
+
+    if (builtin.os.tag == .wasi) return error.SkipZigTest;
+
+    const allocator = std.testing.allocator;
+
+    const max_header_size = 8192;
+    var server = std.http.Server.init(allocator, .{ .reuse_address = true });
+    defer server.deinit();
+
+    const address = try std.net.Address.parseIp("127.0.0.1", 0);
+    try server.listen(address);
+    const server_port = server.socket.listen_address.in.getPort();
+
+    const thread = try std.Thread.spawn(.{}, (struct {
+        fn apply(s: *std.http.Server) !void {
+            const res = try s.accept(.{ .dynamic = max_header_size });
+            defer res.reset();
+            try res.wait();
+
+            const server_body: []const u8 = "message from server!\n";
+            res.transfer_encoding = .{ .content_length = server_body.len };
+            try res.headers.append("content-type", "text/plain");
+            try res.headers.append("connection", "close");
+            try res.do();
+
+            var buf: [128]u8 = undefined;
+            const n = try res.readAll(&buf);
+            try testing.expect(std.mem.eql(u8, buf[0..n], "Hello, World!\n"));
+            _ = try res.writer().writeAll(server_body);
+            try res.finish();
+        }
+    }).apply, .{&server});
+
+    var uri_buf: [22]u8 = undefined;
+    const uri = std.Uri.parse(try std.fmt.bufPrint(&uri_buf, "http://127.0.0.1:{d}", .{server_port})) catch unreachable;
+    var client = std.http.Client{ .allocator = allocator };
+    defer client.deinit();
+    var client_headers = std.http.Headers{ .allocator = allocator };
+    defer client_headers.deinit();
+    var client_req = try client.request(.POST, uri, client_headers, .{});
+    defer client_req.deinit();
+
+    client_req.transfer_encoding = .{ .content_length = 14 }; // this will be checked to ensure you sent exactly 14 bytes
+    try client_req.start(); // this sends the request
+    try client_req.writeAll("Hello, ");
+    try client_req.writeAll("World!\n");
+    try client_req.finish();
+    try client_req.do(); // this waits for a response
+
+    const body = try client_req.reader().readAllAlloc(allocator, 8192 * 1024);
+    defer allocator.free(body);
+    try testing.expect(std.mem.eql(u8, body, "message from server!\n"));
+
+    thread.join();
+}
diff --git a/lib/std/http/Server.zig b/lib/std/http/Server.zig
index 445a10bf48..b1205594ad 100644
--- a/lib/std/http/Server.zig
+++ b/lib/std/http/Server.zig
@@ -338,6 +338,9 @@ pub const Response = struct {
 
     /// Reset this response to its initial state. This must be called before handling a second request on the same connection.
     pub fn reset(res: *Response) void {
+        res.request.headers.deinit();
+        res.headers.deinit();
+
         switch (res.request.compression) {
             .none => {},
             .deflate => |*deflate| deflate.deinit(),
@@ -357,7 +360,7 @@ pub const Response = struct {
                 res.request.parser.header_bytes.deinit(res.server.allocator);
             }
 
-            res.* = undefined;
+            res.server.allocator.destroy(res);
         } else {
             res.request.parser.reset();
         }